通达信最全面的基本面主图显示了此股的主要关键的财务指标以能它所属的各种概念(F10)

有了这个公式可以不要再频繁地去按F10了，主图上清清楚楚地显示了此股的主要关键的财务指标以能它所属的各种概念。
 

下面的是冷妞妞老师编写的，我也组合在一起的，感谢冷妞妞老师。

【说明：早盘如果持有的股票：板弱、股弱。遇到急拉，坚决高抛低吸。】
 【如果板强、股弱：等待股弱转股强。如果盘中一直处于板强、股弱：坚决做T】
 【遇到板强、股强：持股不动。遇到板弱、股强：看个股量，如果放量强持股不动。如果急拉不放量，应高抛低吸】
 【遇到上涨家数迅速增加：考虑补仓或者持股不动，反之减仓。】
 

{所属行业及板块}
DRAWTEXT_FIX(1,0.00,0,0,'所属行业：')COLOR0080FF;
DRAWTEXT_FIX(1,0.07,0,0,HYBLOCK)COLOR0080FF;
DRAWTEXT_FIX(1,0.14,0,0,'所属地区：')COLOR00FFFF;
DRAWTEXT_FIX(1,0.21,0,0,DYBLOCK)COLOR00FFFF;
DRAWTEXT_FIX(1,0.28,0,0,'概念板块：')COLOR00FFFF;
DRAWTEXT_FIX(1,0.35,0,0,GNBLOCK)COLOR00FFFF;
DRAWTEXT_FIX(1,0.00,0.06,0,'重要参考：')COLOR0000FF;
DRAWTEXT_FIX(1,0.07,0.06,0,'每股净资产：'),COLOR0000FF;
DRAWNUMBER_FIX(1,0.14,0.06,0,FINANCE(34));
DRAWTEXT_FIX(1,0.18,0.06,0,'每股未分配利润：'),COLOR0000FF;
DRAWNUMBER_FIX(1,0.28,0.06,0,FINANCE(32));
DRAWTEXT_FIX(1,0.32,0.06,0,'每股公积金：'),COLOR0000FF;
DRAWNUMBER_FIX(1,0.40,0.06,0,FINANCE(18));
DRAWTEXT_FIX(1,0.45,0.06,0,'【说明：每股净资产高于*元，但越高越好!每股未分配利润在*元以上，是比较正常的】'),COLOR0000FF;
DRAWTEXT_FIX(1,0.00,0.12,0,'财务分折：')COLORMAGENTA;
DRAWTEXT_FIX(1,0.07,0.06,0,EXTERNSTR(0,1))COLOR0000FF;

{股本市值}
总股本:=STRCAT(STRCAT('总股本: ',CON2STR(TOTALCAPITAL/1000000,2)),'亿');
流通盘:=STRCAT(STRCAT(' 流通盘: ',CON2STR(CAPITAL/1000000,2)),'亿');
全流通:=STRCAT(' 全流通: ',CON2STR((CAPITAL/1000000)/(TOTALCAPITAL/1000000),2));
市值:=STRCAT(STRCAT(' 流通市值: ',CON2STR((CAPITAL/1000000)*C,2)),'亿');
上市天数:=STRCAT(' 上市天数: ',CON2STR(FINANCE(42),0));
{上市日期:=STRCAT(' 上市日期: ',CON2STR(HHV((BARSCOUNT(C)=0)*(DATE+19000000),0),0));}
股本市值:=STRCAT('股本市值: ',STRCAT(STRCAT(STRCAT(STRCAT(总股本,流通盘),全流通),市值),上市天数));

{业绩综合}
市盈率:=STRCAT('市盈率: ',CON2STR(C/FINANCE(33),2));
市销率:=STRCAT(' 市销率: ',CON2STR(C/(FINANCE(20)/FINANCE(1)),2));
市净率:=STRCAT(' 市净率: ',CON2STR(C/FINANCE(34),2));
净资收益率:=STRCAT(' 净资收益率: ',CON2STR(FINANCE(33)/FINANCE(34)*100,2));
毛利率:=STRCAT(' 毛利率: ',CON2STR((FINANCE(20)-FINANCE(21))/FINANCE(20)*100,2));
净利润率:=STRCAT(' 净利润率 ',CON2STR(FINANCE(30)/FINANCE(20)*100,2));
主营利润率:=STRCAT(' 主营利润率 ',CON2STR(FINANCE(23)/FINANCE(20)*100,2));
当前业绩:=STRCAT('当前业绩: ',STRCAT(STRCAT(STRCAT(STRCAT(STRCAT(STRCAT(市盈率,市销率),市净率),净资收益率),毛利率),净利润率),主营利润率));

{风险系数}
X1:=(FINANCE(11)-FINANCE(15))/FINANCE(10)*1.2;
X2:=(FINANCE(31)+FINANCE(17))/FINANCE(10)*1.4;{盈余公积用资本公积金代替};
X3:=FINANCE(23)/FINANCE(10)*3.3;
X4:=FINANCE(19)/FINANCE(15)*0.6;{缺长期负债或负债总额}
X5:=FINANCE(20)/FINANCE(15)*0.999;
Z值:=X1+X2+X3+X4+X5;
预警:=IF(Z值<1.2,'重警',IF(Z值>=1.2 AND Z值<2.6,'轻警','无警'));
财务预警:=STRCAT('财务预警: ',STRCAT(预警,STRCAT('-Z值: ',CON2STR(Z值,3))));
优质资产率:=STRCAT(' 优质资产率: ',CON2STR((FINANCE(19)-FINANCE(22)-FINANCE(27))/FINANCE(19),2));{理论上越大越好但不同行业有不同标准};
现金负债比:=STRCAT(' 现金负债比: ',CON2STR(FINANCE(25)/FINANCE(15),3));{缺长期负债或负债总额，理论上越大越好但不同行业有不同标准};
财务系数:=STRCAT('风险系数: ',STRCAT(STRCAT(财务预警,优质资产率),现金负债比));

{财务分折}
DRAWTEXT_FIX  (1,0.06,0.12,0,'现金流:'),COLOR00CCCC;
DRAWNUMBER_FIX(1,0.10,0.12,0,CONST(FINANCE(25)/1000000000)),COLOR00CCCC;
DRAWTEXT_FIX  (1,0.145,0.12,0,'应收款:'),COLOR00CCCC;
DRAWNUMBER_FIX(1,0.190,0.12,0,CONST(FINANCE(22)/100000000)),COLOR00CCCC;
DRAWTEXT_FIX  (1,0.243,0.12,0,'存货:'),COLOR00CCCC;
DRAWNUMBER_FIX(1,0.280,0.12,0,CONST(FINANCE(27)/100000000)),COLOR00CCCC;
DRAWTEXT_FIX(1,0.333,0.12,0,'流动比率:'),COLOR00CCCC;{流动比率值>1.5<2.5较为合理，低于1说明偿债能力欠佳。}
DRAWNUMBER_FIX(1,0.389,0.12,0,CONST(FINANCE(11)/FINANCE(15))),COLOR00CCCC;
DRAWTEXT_FIX(1,0.436,0.12,0,'速动比率:'),COLOR00CCCC;
DRAWNUMBER_FIX(1,0.500,0.12,0,CONST(FINANCE(11)-FINANCE(27)/FINANCE(15))),COLOR00CCCC;
DRAWTEXT_FIX  (1,0.63,0.12,0,'套牢盘%:'),COLOR00CCCC;
DRAWNUMBER_FIX(1,0.687,0.12,0,CONST(100-WINNER(CLOSE)*100)),COLOR00CCCC;

DRAWTEXT_FIX  (1,0.415,0.30,0,'流动债:'),COLORGREEN;
DRAWNUMBER_FIX(1,0.465,0.30,0,CONST(FINANCE(15)/100000000)),COLORGREEN;
DRAWTEXT_FIX  (1,0.520,0.30,0,'长期债:'),COLORGREEN;
DRAWNUMBER_FIX(1,0.560,0.30,0,CONST(FINANCE(16)/100000000)),COLORGREEN;
{}
DRAWTEXT_FIX(ISLASTBAR,0.00,0.18,0,股本市值),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR,0.00,0.24,0,当前业绩),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR,0.00,0.30,0,财务系数),COLORGREEN;

{行业板块看盘幅图}

创业板:=INBLOCK('创业板');
中小企业:=INBLOCK('中小企业');
上证Ａ股:=INBLOCK('上证Ａ股');
深证Ａ股:=INBLOCK('深证Ａ股');
INDEH:=IF(中小企业=1,"399005$H",IF(创业板=1,"399006$H",IF(上证Ａ股=1,"999999$H","399001$H"))),NODRAW;
INDEO:=IF(中小企业=1,"399005$O",IF(创业板=1,"399006$O",IF(上证Ａ股=1,"999999$O","399001$O"))),NODRAW;
INDEL:=IF(中小企业=1,"399005$L",IF(创业板=1,"399006$L",IF(上证Ａ股=1,"999999$L","399001$L"))),NODRAW;
INDEC:=IF(中小企业=1,"399005$C",IF(创业板=1,"399006$C",IF(上证Ａ股=1,"999999$C","399001$C"))),NODRAW;
板块:=IF(中小企业=1,'中小企业指数',IF(创业板=1,'创业板指数',IF(上证Ａ股=1,'上证指数','深证指数')));
AA:=REF(INDEC,1);
指数涨幅:=IF(AA>0,(INDEC-AA)*100/AA,0);
A:=STRCAT(板块,STRCAT(':',CON2STR(INDEC,2)));
B:=STRCAT('指数涨跌：',CON2STR(指数涨幅,2));
DRAWTEXT_FIX(ISLASTBAR,0,0.36,0,A),COLOR0055FF;
DRAWTEXT_FIX(ISLASTBAR,0.12,0.36,0,B),COLOR0055FF;

CCC:=HY_INDEXC;
OOO:=HY_INDEXO;
LLL:=HY_INDEXL;
HHH:=HY_INDEXH;
DRAWKLINE(HHH,OOO,LLL,CCC);
上涨:=VARCAT('上涨：',VAR2STR(HY_INDEXADV,0));
下跌:=VARCAT('下跌：',VAR2STR(HY_INDEXDEC,0));
DRAWTEXT_FIX(ISLASTBAR,0.22,0.36,0,上涨),COLORMAGENTA;
DRAWTEXT_FIX(ISLASTBAR,0.29,0.36,0,下跌),COLORYELLOW;

A1:=REF(CCC,1);
ZF:=(C-REF(C,1))/REF(C,1)*100;
行业指数:=IF(A1>0,(CCC-A1)*100/A1,0);
DD:=STRCAT('行业指数：',CON2STR(CCC,2));
E:=STRCAT('行业涨跌：',CON2STR(行业指数,2));

DRAWTEXT_FIX(ISLASTBAR,0.44,0.36,0,DD),COLORYELLOW;
DRAWTEXT_FIX(ISLASTBAR,0.57,0.36,0,E),COLORYELLOW;
{DRAWTEXT_FIX(ISLASTBAR,0.7,0.38,0,HYBLOCK),COLORYELLOW;}{所属行业}

DRAWTEXT_FIX(ISLASTBAR AND 指数涨幅<=行业指数,0.36,0.36,0,'板强'),COLORRED;
DRAWTEXT_FIX(ISLASTBAR AND 指数涨幅>行业指数,0.36,0.36,0,'板弱'),COLORCYAN;
DRAWTEXT_FIX(ISLASTBAR AND ZF>=行业指数,0.40,0.36,0,'股强'),COLORRED;
DRAWTEXT_FIX(ISLASTBAR AND ZF<行业指数,0.40,0.36,0,'股弱'),COLORCYAN;

DRAWTEXT_FIX(1,0.0,0.43,0,'【说明：早盘如果持有的股票：板弱、股弱。遇到急拉，坚决高抛低吸。】'),COLOR0080FF;
DRAWTEXT_FIX(1,0.0,0.50,0,'【如果板强、股弱：等待股弱转股强。如果盘中一直处于板强、股弱：坚决做T】'),COLOR0080FF;
DRAWTEXT_FIX(1,0.0,0.57,0,'【遇到板强、股强：持股不动。遇到板弱、股强：看个股量，如果放量强持股不动。如果急拉不放量，应高抛低吸】'),COLOR0080FF;
DRAWTEXT_FIX(1,0.0,0.64,0,'【遇到上涨家数迅速增加：考虑补仓或者持股不动，反之减仓。】'),COLOR0080FF;