冷妞妞11指标整合修订版集合公式 希望大家喜欢

冷妞妞美女 老师 人气鼎沸 热心助人.有目共睹.在次祝妞妞美女节日快乐！

 今天下载 妞妞老师的11指标整合版. 原本的意思是修改一下.自己喜欢的风格.更直观.层次分明.修改一下 发现一个小问题.很小的问题.被我发现.嘿嘿！！
 发这一贴  来沾一沾老师的光.~~~~

 
{联合看盘幅图之五}

顶:200,POINTDOT,COLORWHITE;
上升趋势:180,POINTDOT,COLORBLUE;
下降趋势:160,POINTDOT,COLORGREEN;
强过三峰:140,POINTDOT,COLORCYAN;
快进快去:120,POINTDOT,COLORRED;
量能饱和:100,POINTDOT,COLORMAGENTA;
突破天量:80,POINTDOT,COLORBROWN;
强过四峰:60,POINTDOT,COLORGRAY;
锅里捞金:40,POINTDOT,COLORLIRED;
破指MC:20,POINTDOT,COLORYELLOW;
量价选股:0,POINTDOT,COLOR5C3317;
破锅回踩:-20,POINTDOT,COLORLIMAGENTA;
M5:=MA(C,5);
M10:=MA(C,10);
M20:=MA(C,20);
M60:=MA(C,60);
A:=M5>=M60 AND M10>=M60 AND M20>=M60;
T:=BARSLAST(CROSS(A,0.5));
JD:=(ATAN((M60/REF(M60,T)-1)*100)*180/3.1415926);
ZF:=(C-REF(C,T+1))/REF(C,T+1)*100;
LL:=MIN(MIN(M5,M10),M20);
TJ1:=EVERY(LL>M60,T);
TJ:=V=HHV(V,60) AND C>REF(C,1)*1.08 AND TJ1 AND ZF<60 AND JD>80;
T1:=BARSSINCEN(TJ,T+1);
NOTEXT1:=DRAWLINE(T=0,REF(H,T),T1=0,REF(H,T1),1);
TJA:=EVERY(C<NOTEXT1,T1);
XG:=REF(TJA,1) AND CROSS(C,NOTEXT1) AND T>30;
DRAWTEXT_FIX(ISLASTBAR,0.95,0.04,0,'上升趋势 '),COLORBLUE;
STICKLINE(XG,180,200,1.9,180),COLORBLUE;
AT:=HHVBARS(M5,60);
AVV:=IF(C<O OR (C=O AND C<REF(C,1)),VOL,-999);
AT1:=BARSLAST(M5<REF(M5,AT) AND AVV=HHV(AVV,AT) AND H<REF(H,AT));
AA:=DRAWLINE(AT=0,REF(H,AT),AT1=0 AND AT>10,REF(H,AT1),1);
AGL:=(C/AA-1)*100;
ATJ:=EVERY(AGL<3,T);
AXL:=HHV(AA/M5,AT1);
AXG:=REF(ATJ,1) AND CROSS(C,AA) AND AGL>4 AND AT1>1 AND AXL<1.2;
DRAWTEXT_FIX(ISLASTBAR,0.95,0.12,0,'下降趋势'),COLORGREEN;
STICKLINE(AXG,160,180,1.9,160),COLORGREEN;
BHT:=HHVBARS(H,10);
BHTT:=BARSLAST(REF(BHT,1)>=4 AND BHT=0);
BHH1:=REF(H,BHTT);
BHH2:=REF(BHH1,BHTT+1);
BHH3:=REF(BHH2,BHTT+1);
BHH:=MAX(MAX(BHH1,BHH2),BHH3);
BLL:=MIN(MIN(BHH1,BHH2),BHH3);
BGL:=BHH/BLL;
BTJ:=COUNT(BHTT=0,30)>=3;
BTJ1:=BGL<=1.04;
XG1:=BTJ1 AND BTJ AND H=HHV(H,30);
BXG:=COUNT(XG1,30)=1 AND XG1;
DRAWTEXT_FIX(ISLASTBAR,0.95,0.2,0,'强过三峰'),COLORCYAN;
STICKLINE(BXG,140,160,1.9,140),COLORCYAN;
K:=KDJ.K;
D:=KDJ.D;
J:=KDJ.J;
CHH:=MAX(MAX(K,D),J);
CLL:=MIN(MIN(K,D),J);
CNH:=(CHH/CLL-1)*100;
CA:=K>D AND J>K;
CT:=BARSLAST(CROSS(CNH<1,0.5));
CTJ:=MIN(C,O)/L>1.04 AND MIN(C,O)<REF(MIN(C,O),1);
CTJ1:=IF(C<O,H/O>1.005,C>=O);
CXG:=REF(CA,CT+1) AND COUNT(CNH>1,CT)=1 AND CNH>1 AND CTJ AND CTJ1;
DRAWTEXT_FIX(ISLASTBAR,0.95,0.29,0,'快进快去'),COLORRED;
STICKLINE(CXG,120,140,1.9,120),COLORRED;
DSAT:=(AMOUNT/C)/(HHV(AMOUNT,20)/HHV(C,20));
DBD:=IF(DSAT>1,1,DSAT)*100;
DX2:=AMOUNT/VOL/100;
DM13:=MA(DX2,13);
DJD:=(ATAN((MA(DX2,10)/REF(MA(DX2,10),1)-1)*100)*180/3.1415926);
DA:=COUNT(DJD>45,15)=1 AND DJD>45;
DHH:=MAX(MAX(MAX(M5,M10),DM13),M20);
DLL:=MIN(MIN(MIN(M5,M10),DM13),M20);
DNH:=(DHH/DLL-1)*100;
DA1:=M5>MAX(MAX(M10,DM13),M20);
DTJ:=DA AND DBD=100 AND V=HHV(V,30) AND C>O;
DTJ1:=DA1 AND MIN(MIN(M5,M10),M20)>M60 AND DNH<4.2;
DXG:=DTJ AND DTJ1;
DRAWTEXT_FIX(ISLASTBAR,0.95,0.37,0,'量能饱和'),COLORMAGENTA;
STICKLINE(DXG,100,120,1.9,100),COLORMAGENTA;
ET:=BARSLAST(H=HHV(H,100) AND V=HHV(V,500));
EHT:=BARSLAST(H=HHV(H,ET+1));
EHT1:=BARSLAST(EVERY(H<REF(H,EHT),EHT) AND CROSS(EHT>=80,0.5));
EEXT:=DRAWLINE(EHT=0,REF(H,EHT),EHT1=0,REF(H,EHT),1);
ETT:=BARSLAST(CROSS(EEXT>=0,0.5));
EXG:=COUNT(CROSS(C>=EEXT,0.5),ETT+1)=1 AND CROSS(C>=EEXT,0.5);
DRAWTEXT_FIX(ISLASTBAR,0.95,0.45,0,'突破天量'),COLORBROWN;
STICKLINE(EXG,80,100,1.9,80),COLORBROWN;
FN:=40;
FT:=BARSLAST(H<REF(H,1) AND REF(H,1)>REF(H,2));
FHH:=REF(H,FT+1);
FLL:=FINDLOW(L,FT=0,10,1);
FLH:=SUM(H>REF(H,1),10);
FZF:=(FHH-FLL)/FLL*100;
FTT:=BARSLAST(FT=0 AND FZF>20 AND FLH>2);
FT1:=SUMBARS(FTT=0,1);
FT2:=SUMBARS(FTT=0,2);
FT3:=SUMBARS(FTT=0,3);
FT4:=SUMBARS(FTT=0,4);
FH1:=REF(FHH,FT1-1);
FH2:=REF(FHH,FT2-1);
FH3:=REF(FHH,FT3-1);
FH4:=REF(FHH,FT4-1);
FAH:=MAX(MAX(MAX(FH1,FH2),FH3),FH4);
FAL:=MIN(MIN(MIN(FH1,FH2),FH3),FH4);
FBL:=FAH/FAL<1.15;
FTJ:=COUNT(CROSS(C,FH1),FTT+1)=1 AND CROSS(C,FH1);
FTJ1:=FH4<FH3 AND FH3<FH2 AND FH2<FH1;
FA:=FTJ AND FBL AND FT4<FN AND FTJ1;
FXG:=COUNT(FA,FT4+1)=1 AND FA;
DRAWTEXT_FIX(ISLASTBAR,0.95,0.55,0,'强过四峰'),COLORGRAY;
STICKLINE(FXG,60,80,1.9,60),COLORGRAY;
GLT:=LLVBARS(L,60);
GLTT:=BARSLAST(CURRBARSCOUNT=CONST(GLT)+1);
GHT:=FINDHIGHBARS(H,GLT+1,60,1);
GTT:=BARSLAST(CURRBARSCOUNT=CONST(GHT)+1);
GHJ:=REF((REF(H,GTT)-L)*0.618+L,GLTT);
GV1:=IF(C>O OR (C=O AND C>=REF(C,1)),VOL,0);
GV2:=IF(C<O OR (C=O AND C<REF(C,1)),VOL,0);
GLJ:=SUM(GV1,GLTT)/SUM(GV2,GLTT);
GXG:=COUNT(CROSS(C>=GHJ,0.5),GLTT+1)=1 AND CROSS(C>=GHJ,0.5) AND GLJ>1.5;
DRAWTEXT_FIX(ISLASTBAR,0.95,0.65,0,'锅里捞金'),COLORLIRED;
STICKLINE(GXG,40,60,1.9,40),COLORLIRED;
DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD:=(DIF-DEA)*2;
IT:=BARSLAST(CROSS(DEA,DIF));
IHT:=BARSLAST( HHV(DEA,15)=DEA);
IGT:=BARSLAST(IT=0 AND REF(IHT,1)=0 AND DEA>0);
IGM:=REF(DEA,IGT);
IEXT:=DRAWLINE(IGT=0,DEA,IT=0 AND (REF(IGM,1)-DEA)>0.75 AND DEA>0,REF(DEA,IT),1);
IXG:=CROSS(DEA,IEXT);
DRAWTEXT_FIX(ISLASTBAR,0.95,0.75,0,'破指MC'),COLORYELLOW;
STICKLINE(IXG,20,40,1.9,20),COLORYELLOW;
KN:=30;
KT1:=BARSLAST(H=HHV(H,KN));
KT2:=BARSLAST(L=LLV(L,KN));
KT3:=BARSLAST(VOL=HHV(VOL,KN));
KT4:=BARSLAST(VOL=LLV(VOL,KN));
KHH:=HHV(IF(KT1=0,H,-999),3);
KLL:=LLV(IF(KT2=0,L,999),3);
KVH:=HHV(IF(KT3=0,VOL,-999),3);
KVL:=LLV(IF(KT4=0,VOL,9999999999),3);
KH1:=FINDHIGH(KHH,0,KN,1);
KH2:=FINDHIGH(KHH,0,KN,2);
KH3:=FINDHIGH(KHH,0,KN,3);
KL1:=FINDLOW(KLL,0,KN,1);
KL2:=FINDLOW(KLL,0,KN,2);
KL3:=FINDLOW(KLL,0,KN,3);
KVH1:=FINDHIGH(KVH,0,KN,1);
KVH2:=FINDHIGH(KVH,0,KN,2);
KVH3:=FINDHIGH(KVH,0,KN,3);
KVL1:=FINDLOW(KVL,0,KN,1);
KVL2:=FINDLOW(KVL,0,KN,2);
KVL3:=FINDLOW(KVL,0,KN,3);
KPH:=(KH1+KH2+KH3)/3;
KPL:=(KL1+KL2+KL3)/3;
KPVH:=(KVH1+KVH2+KVH3)/3;
KPVL:=(KVL1+KVL2+KVL3)/3;
KTJ:=KPH/KPL;
KTJ1:=KPVH/KPVL>1.5;
KTJ2:=C>(KPH+KPL)/2 AND C>MA(C,10);
KXG:=CROSS(RANGE(KTJ,1.2,1.3) AND KTJ1,0.5);
DRAWTEXT_FIX(ISLASTBAR,0.95,0.85,0,'量价选股'),COLORWHITE;
STICKLINE(KXG,0,20,1.9,0),COLORWHITE;
QLT:=LLVBARS(L,60);
QLTT:=BARSLAST(CURRBARSCOUNT=CONST(QLT)+1);
QHT:=FINDHIGHBARS(H,QLT+1,60,1);
QTT:=BARSLAST(CURRBARSCOUNT=CONST(QHT)+1);
QT:=BARSLAST(CROSS(C,REF(H,QTT)));
QGL:=C/REF(H,QTT);
QTA:=BARSLAST(QGL=HHV(QGL,QT+1));
QDF:=(C-REF(C,QTA+1))/REF(C,QTA+1)*100;
QJL:=L/REF(H,QTT);
QXG1:=QDF<-8 AND QJL<1.075 AND MIN(C,O)*1.005>=REF(H,QTT);
QXG:=COUNT(QXG1,QT+1)=1 AND QXG1;
DRAWTEXT_FIX(ISLASTBAR,0.95,0.92,0,'破锅回踩'),COLORLIMAGENTA;
STICKLINE(QXG,-20,0,1.9,-20),COLORLIMAGENTA;